「Rhuno Flash Blog > How to compile for Flash Player 10.2 with Flash CS5」を日本語訳しただけだと思ってください。簡単な英語が読める方は、上記のリンク先ページの最後の方に、必要なファイルと手順をまとめてくれているzipファイルがあるのでそれを使うと楽です。コメント欄に追記があるのでちゃんと見てください。

そうでない方は以下の手順。
元のページがWin向けだったので、ここではMac向けに書きます。

1. FlexSDKのダウンロード

ここからFlexSDK（2011.5.13時点では4.5.0.20967が最新）をダウンロード。「Adobe Flex SDK」で大丈夫です。

2. playerglobal.swcのコピー

「/アプリケーション/Adobe Flash CS5/Common/Configuration/ActionScript 3.0」に「FP10.2」フォルダを作成し、その中に先ほどダウンロードした「flex_sdk_4.5.0.20967/frameworks/libs/player/10.2/playerglobal.swc」をコピーして下さい。

3. XMLファイルを作成

「/アプリケーション/Adobe Flash CS5/Common/Configuration/Players」の「FlashPlayer10_1.xml」をコピーして、ファイル名を「FlashPlayer10_2.xml」に変更。このXMLファイルをテキストエディタなどで開き、以下の行を変更。
3行目　playerノード　”FlashPlayer10″ を “FlashPlayer10.2″ にして、さらにversion を “11″ に変更
4行目　nameノード　”Flash Player 10.2″ に変更
8行目　playerDefinitionPath の as3= 以降を “$(AppConfig)/ActionScript 3.0/FP10.2/playerglobal.swc” に変更

4. FlashPlayerを更新

これは参考サイトに書かれていなかったのですが、ここから最新のFlashPlayerをダウンロードして「/アプリケーション/Adobe Flash CS5/Players」内の各Player（DebugやReleaseも）を最新のもので上書きした方がいいと思います。

5. 動作確認

Flashを再起動後、パブリッシュ設定に「FlashPlayer10.2」が追加されているはずです。てきとうなファイルを作り、動作確認してください。

6. 注意事項

一部のAPI（StageVideoなど？）を使うと、プレビューではエラーが出たりする場合があるようです。今のところデバッグやパブリッシュでは問題なく動きましたが、自分も今日したばっかりなのであまり検証していません。以上です。

package {
	import flash.display.Graphics;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.geom.Point;
	import flash.utils.getTimer;

	public class Main extends MovieClip {

		private var tracks:Vector.<Vector.<Track>>;

		public function Main():void {

			//初期化
			tracks = new Vector.<Vector.<Track>>();

			//リスナー登録
			this.addEventListener(Event.ENTER_FRAME, Draw);
			stage.addEventListener(MouseEvent.MOUSE_DOWN, Begin);
		}

		//ドラッグ開始
		private function Begin(e:MouseEvent):void {

			//更新
			Update(mouseX, mouseY, getTimer(), true);

			//リスナー登録
			stage.addEventListener(Event.ENTER_FRAME, Move);
			stage.addEventListener(MouseEvent.MOUSE_UP, Finish);
		}

		//ドラッグ中
		private function Move(e:Event):void {

			//更新
			Update(mouseX, mouseY, getTimer(), false);
		}

		//ドラッグ終了
		private function Finish(e:MouseEvent):void {

			//更新
			Update(mouseX, mouseY, getTimer(), false);

			//リスナー解除
			stage.removeEventListener(Event.ENTER_FRAME, Move);
			stage.removeEventListener(MouseEvent.MOUSE_UP, Finish);
		}

		//更新
		private function Update(_x:int, _y:int, _t:int, _s:Boolean):void {

			//データ追加
			if (!_s) _s = Boolean(tracks.length == 0);
			if (_s) tracks.unshift(new Vector.<Track>());
			tracks[0].unshift(new Track(_x, _y, _t));
		}

		//描画
		private function Draw(e:Event):void {

			//変数
			var t:uint = getTimer();
			var a:int = tracks.length;
			var b:int;
			var c:Boolean;
			var i:int;
			var j:int;
			var g:Graphics = this.graphics;

			//描画
			g.clear();
			if (a > 0) {
				for (i = a - 1; i >= 0; i --) {
					b = tracks[i].length;
					c = true;
					if (b > 0) {
						for (j = b - 1; j >= 0; j --) {
							if (t - tracks[i][j].t > 1000) {
								tracks[i].splice(j, 1);
								if (j == 0) tracks.splice(i, 1);
							}
							else {
								if (c) {
									c = false;
									g.lineStyle();
									g.moveTo(tracks[i][j].x, tracks[i][j].y);
									g.beginFill(0xFFFFFF, 1.0);
									g.drawCircle(tracks[i][j].x, tracks[i][j].y, 3);
									g.endFill();
									g.lineStyle(6, 0xFFFFFF, 1.0, false);
								}
								g.lineTo(tracks[i][j].x, tracks[i][j].y);
							}
						}
					}
				}
			}
		}
	}
}

//軌跡クラス
class Track {
	public var x:int;
	public var y:int;
	public var t:int;
	public function Track(_x:int, _y:int, _t:int):void {
		x = _x;
		y = _y;
		t = _t;
	}
}

デバイスを一つしか使わない（MacBookのトラックパッドやiMacにMagicTrackpad）場合はopenFrameworks.jp forum 「MacBookProのトラックパッドでマルチタッチ」のサンプルとかリンク先を見てください。

ここではすでにトラックパッドが搭載されているMacBookにMagicTrackpadをつないでMagicTrackpad側を認識したい場合、など複数のデバイスを混在させoFで認識させる方法について書きます。基本は上のサンプルとほとんど同じで、デバイスの取得で使う関数がObjective-Cで動作させる必要があるので少し変更が必要です。下記コードの変更は24行目と78～82行目の部分がメイン。

まず、oFのemptyExampleをコピーして、addonsの「ofxVectorMath」とフレームワークの「MultitouchSupport.framework」を読み込みます。次に「testApp.cpp」を「testApp.mm」に名称変更し、右クリック>情報を見る>ファイルタイプで「sourcecode.cpp.cpp」を「sourcecode.cpp.objcpp」に変更します。そしてtestApp.mmには以下のコード。

#include "testApp.h"
#include "ofxVectorMath.h"

extern "C" {
	typedef struct { float x,y; } mtPoint;
	typedef struct { mtPoint pos,vel; } mtReadout;
	typedef struct {
		int frame;
		double timestamp;
		int identifier, state, foo3, foo4;
		mtReadout normalized;
		float size;
		int zero1;
		float angle, majorAxis, minorAxis;
		mtReadout mm;
		int zero2[2];
		float unk2;
	}
	Finger;

	typedef void *MTDeviceRef;
	typedef int (*MTContactCallbackFunction)(int,Finger*,int,double,int);

	CFMutableArrayRef MTDeviceCreateList(void);
	void MTRegisterContactFrameCallback(MTDeviceRef, MTContactCallbackFunction);
	void MTDeviceStart(MTDeviceRef, int);
}

class TouchPoint {
public:
	ofxVec2f pos;
	float size;
	int id;
	bool enable;
	float phase;
	float freq, amp;
	float trem_phase;
};

vector<TouchPoint> touchPoints;

int mtCallback(int device, Finger *data, int nFingers, double timestamp, int frame) {
	for (int i = 0; i < touchPoints.size(); i  ++) {
		touchPoints[i].enable = false;
	}
	for (int i=0; i<nFingers; i++) {
		Finger *f = &data[i];

		/*
		 printf("Frame %7d: Angle %6.2f, ellipse %6.3f x%6.3f; "
			"position (%6.3f,%6.3f) vel (%6.3f,%6.3f) "
			"ID %d, state %d [%d %d?] size %6.3f, %6.3f?n",
			f->frame,
			f->angle * 90 / atan2(1,0),
			f->majorAxis,
			f->minorAxis,
			f->normalized.pos.x,
			f->normalized.pos.y,
			f->normalized.vel.x,
			f->normalized.vel.y,
			f->identifier, f->state, f->foo3, f->foo4,
			f->size, f->unk2);
		 */

		TouchPoint &t = touchPoints[f->identifier];
		t.pos.x = f->normalized.pos.x;
		t.pos.y = 1 - f->normalized.pos.y;
		t.size = f->size;
		t.enable = true;
		t.id = f->identifier;
	}
	return 0;
}

void testApp::setup() {
	touchPoints.resize(20);

	NSMutableArray* deviceList = (NSMutableArray*)MTDeviceCreateList();
	for(int i = 0; i < [deviceList count]; i ++) {
		MTRegisterContactFrameCallback([deviceList objectAtIndex:i], mtCallback);
		MTDeviceStart([deviceList objectAtIndex:i], 0);
	}

	ofEnableSmoothing();
	ofEnableAlphaBlending();
	ofSetVerticalSync(true);
	ofSetFrameRate(60);

	ofHideCursor();

	ofBackground(0, 0, 0);

	ofSetColor(255, 255, 255);
	ofNoFill();
}

void testApp::update() {
}

void testApp::draw() {
	for (int i = 0; i < touchPoints.size(); i++)
	{
		TouchPoint &t = touchPoints[i];

		if (t.enable == false) continue;

		float xx = t.pos.x * ofGetWidth();
		float yy = t.pos.y * ofGetHeight();
		ofCircle(xx, yy, t.size * 50);

		ofDrawBitmapString(ofToString(t.freq, 1), xx, yy);
	}
}

void testApp::keyPressed(int key) {
}

void testApp::keyReleased(int key) {
}

void testApp::mouseMoved(int x, int y){
}

void testApp::mouseDragged(int x, int y, int button) {
}

void testApp::mousePressed(int x, int y, int button) {
}

void testApp::mouseReleased(int x, int y, int button) {
}

void testApp::windowResized(int w, int h) {
}

//Main.as

package {
	import caurina.transitions.Tweener;
	import flash.display.Graphics;
	import flash.display.MovieClip;
	import flash.events.KeyboardEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;

	public class Main extends MovieClip {

		private var Circle_mc:MovieClip;

		public function Main():void {

			//円
			Circle_mc = new MovieClip();
			Circle_mc.graphics.beginFill(0x999999, 1);
			Circle_mc.graphics.drawCircle(0, 0, 50);
			Circle_mc.x = 170;
			Circle_mc.y = stage.stageHeight / 2;
			this.addChild(Circle_mc);

			//説明文
			var Text_tf:TextField = new TextField();
			Text_tf.textColor = 0xFFFFFF;
			Text_tf.text = "KeyDown (ON/OFF)n1 : nonen2 : linearn3 : easeInOutCubic";
			Text_tf.x = Text_tf.y = 10;
			Text_tf.autoSize = TextFieldAutoSize.LEFT;
			this.addChild(Text_tf);

			//リスナー登録
			stage.addEventListener(KeyboardEvent.KEY_DOWN, KeyDown);
		}

		//キーボードが押された場合
		private function KeyDown(e:KeyboardEvent):void {

			//移動
			if (e.keyCode == 49 || e.keyCode == 97) Move("");
			else if (e.keyCode == 50 || e.keyCode == 98) Move("linear");
			else if (e.keyCode == 51 || e.keyCode == 99) Move("easeInOutCubic");
		}

		//移動
		private function Move(_type:String):void {

			//初期化
			Tweener.removeTweens(this);
			Circle_mc.x = 170;

			//トランジションが指定されている場合
			if (_type != "") {
				Tweener.addCaller(this, {
					count		:30,
					time		:3.0,
					transition	:_type,
					onUpdate	:Update
				});
			}

			//トランジションが無指定の場合
			else {
				Tweener.addCaller(this, {
					count		:30,
					time		:3.0,
					onUpdate	:Update
				});
			}

			//トゥイーン中
			function Update():void {
				Circle_mc.x += 10;
			}
		}
	}
}

1. iPhone用Webクリップを変更

img/touch-icon/p2-serif.png を好きな画像に変更
解像度はiPhoneやiPadが勝手にリサイズするので大きめでOK。
同じフォルダ内に他にも画像がいっぱいあるけど何のためだろう？

2. faviconを変更

./favicon.ico を好きな画像に変更

3. スタイルシートを変更

skin/○○○.php を追加（※自分の場合はtmdf.php）
設定管理の「スキン」でそれを指定

4. 2カラムに変更 & 新規タブで開く

設定管理 > ユーザ設定編集 > ETC の
frame_subject_width と frame_read_width を空白に。
このままだとスレ一覧のリンクをクリックした際に見えなくしている
カラムに表示されてしまうので target=”_blank” を下記に追加
lin/sb_print.inc.php の443行目（※各スレッド）
lib/sb_toolbar.inc.php の127行目（※板の新着まとめ読み）

自分が好きな感じのタイプがなかったのでキーボードのグラフィック上にkeyCodeをマッピングしたグラフィックを作りました。ActionScript（Flash）でKeyboardEventを大量に使う時に便利なはず。編集可能なPDFなので好きなようにいじって使ってください。間違えてないはずだけど、間違えてたら直すのでコメントで教えてください。

Download Keycode.pdf

Macの場合、ビルドされた■■■.appを右クリックして「パッケージの内容を表示」し「Contents/support」フォルダ内に「java」フォルダを新規作成。その中に「アプリケーション/Max5/Cycling ’74/java」フォルダ内にある以下のファイルをコピー。
・classes/■■■.class　*使用しているライブラリ
・classes/■■■.java
・lib/max.jar
・max.java.config.txt

Windowsの場合も似たディレクトリになっているので、同じようにファイルをコピー。
これでちゃんと実行されるはず。

注意点は、「コレクティブ / アプリケーションをビルド…」をすると、「含めるフォルダ…」などでインクルードするファイルを指定できますが、上記ファイルを指定してもインクルードされない上に、後でビルドされたアプリにmax.jarをコピーしてもうまく認識されなくなります。なのでmxj関連のファイルは指定しないようにしておきましょう。

上記の環境はMac、WinともにMax5.1.4です。

「standalone」オブジェクトを作り、「インスペクタ」で「Status Window Visible at Statup」をオフにするだけ。

//Main.as

package {
	import caurina.transitions.Tweener;
	import flash.display.Graphics;
	import flash.display.MovieClip;
	import flash.events.KeyboardEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;

	public class Main extends MovieClip {

		private var Circle_mc:MovieClip;
		private var fade:Boolean;
		private var move:Boolean;

		public function Main():void {

			//円
			Circle_mc = new MovieClip();
			Circle_mc.graphics.beginFill(0xFFFFFF, 1);
			Circle_mc.graphics.drawCircle(0, 0, 60);
			Circle_mc.x = 100;
			Circle_mc.y = stage.stageHeight / 2;
			this.addChild(Circle_mc);

			//説明文
			var Text_tf:TextField = new TextField();
			Text_tf.textColor = 0xFFFFFF;
			Text_tf.text = "KeyDown (ON/OFF)n1 : Moven2 : Alphan3 : Both";
			Text_tf.x = Text_tf.y = 10;
			Text_tf.autoSize = TextFieldAutoSize.LEFT;
			this.addChild(Text_tf);

			//動作
			Change("fade", true);
			Change("move", true);

			//リスナー登録
			stage.addEventListener(KeyboardEvent.KEY_DOWN, KeyDown);
		}

		//キーボードが押された場合
		private function KeyDown(e:KeyboardEvent):void {

			//フェードイン（アウト） トグル
			if (e.keyCode == 49 || e.keyCode == 97) Change("fade", !fade);

			//x軸移動 トグル
			else if (e.keyCode == 50 || e.keyCode == 98) Change("move", !move);

			//3 停止（どちらも停止中の場合は開始）
			else if (e.keyCode == 51 || e.keyCode == 99) {
				if (!fade && !move) {
					Change("fade", true);
					Change("move", true);
				}
				else Change("both");
			}
		}

		//動作
		private function Change(_type:String, _value:Boolean = false):void {

			//フェードイン（アウト） 停止
			if (_type == "fade" && !_value) {
				fade = false;
				Tweener.removeTweens(Circle_mc, "alpha");
			}

			//フェードイン（アウト） 開始
			else if (_type == "fade" && _value) {
				fade = true;
				Tweener.addTween(Circle_mc, {
					alpha				:1.0,
					time				:0.5
				});
				Tweener.addTween(Circle_mc, {
					alpha				:0.2,
					delay				:0.5,
					time				:0.5,
					onComplete			:Change,
					onCompleteParams	:["fade", true]
				});
			}

			//x軸移動 停止
			else if (_type == "move" && !_value) {
				move = false;
				Tweener.removeTweens(Circle_mc, "x");
			}

			//x軸移動 開始
			else if (_type == "move" && _value) {
				move = true;
				Tweener.addTween(Circle_mc, {
					x					:stage.stageWidth - 100,
					time				:2.5
				});
				Tweener.addTween(Circle_mc, {
					x					:100,
					delay				:2.5,
					time				:2.5,
					onComplete			:Change,
					onCompleteParams	:["move", true]
				});
			}

			//両方 停止
			else if (_type == "both") {
				fade = false;
				move = false;
				Tweener.removeTweens(Circle_mc, "alpha", "x");
			}
		}
	}
}

//Main.as

package {
	import flash.display.MovieClip;

	public class Main extends MovieClip {

		public function Main():void {

			//数値配列「num」を作成
			var l:uint = 100000;
			var num:Vector.<Number> = new Vector.<Number>();
			for (var i:uint = 0; i < l; i ++) {
				num[i] = Math.random() * l;
			}

			//インデックス位置と数値を記憶する配列を作成
			var sort:Array = new Array();
			for (i = 0; i < l; i ++) {
				sort[i] = {id:i, value:num[i]};
			}

			//元のインデックス位置が4285のデータを記憶
			var search:Object = sort[4285];

			//数値の小さい順に並び替え
			sort.sortOn("value", Array.NUMERIC);

			//元のインデックス位置が4285のデータが何番目に小さい値か？
			trace(sort.indexOf(search));

			//1365番目に小さい値の元のインデックス位置はどこか？
			trace(sort[1365].id);
		}
	}
}

キーダウン 「1」
単純に親mcをフェードアウトした場合。本来なら円が重なったところはそのままの状態でフェードアウトして欲しいのですが、子mcに透明度が別々に割り当てられるせいで、見せたくない部分（青と重なっている緑など）まで透けて見えます。

キーダウン 「2」
「1」をビットマップキャッシュ化した場合。これでうまくいくと思っていたのですが、結果は「1」と変わりません。

キーダウン 「3」
自分の希望はこのタイプ。親mcをそのままビットマップデータに描画、親mcと同階層にそのビットマップを配置。もともとの親mcは非表示にし、ビットマップをフェードアウトさせ、完了と同時にビットマップ（データ）を削除（メモリ開放）しています。

細かい部分は下記コード、または「FadeOut.zip」を参照して下さい。連打した場合の処理はしていません。

もっとスマートな処理がありそうなので、思いついたら追記したいと思います。また、今回のように単純に黒ベタ背景でフェードアウトする場合は、逆に黒ベタを親mcの前面にフェードインさせるのが一番楽です。

//Sample.as

package {
	import caurina.transitions.Tweener;
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.DisplayObject;
	import flash.display.Graphics;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.KeyboardEvent;

	public class Sample extends MovieClip {

		//起動時
		public function Sample():void {

			//リスナー登録
			this.addEventListener(Event.ADDED_TO_STAGE, Init);
		}

		//初期化
		private function Init(e:Event):void {

			//リスナー登録
			this.removeEventListener(Event.ADDED_TO_STAGE, Init);

			//オブジェクト生成
			var g:Graphics;

			//赤
			var Red_mc:MovieClip = new MovieClip();
			g = Red_mc.graphics;
			g.beginFill(0xCC0000);
			g.drawCircle(0, 0, 100);
			this.addChild(Red_mc);
			Red_mc.x = 185;
			Red_mc.y = 150;

			//緑
			var Green_mc:MovieClip = new MovieClip();
			g = Green_mc.graphics;
			g.beginFill(0x33CC00);
			g.drawCircle(0, 0, 100);
			this.addChild(Green_mc);
			Green_mc.x = 285;
			Green_mc.y = 150;

			//青
			var Blue_mc:MovieClip = new MovieClip();
			g = Blue_mc.graphics;
			g.beginFill(0x0033CC);
			g.drawCircle(0, 0, 100);
			this.addChild(Blue_mc);
			Blue_mc.x = 385;
			Blue_mc.y = 150;

			//リスナー解除
			stage.addEventListener(KeyboardEvent.KEY_DOWN, KeyDown);
		}

		//キーボードが押された場合
		private function KeyDown(e:KeyboardEvent):void {

			//1～3
			if (e.keyCode == 49 || e.keyCode == 97) NormalFadeOut(false);
			else if (e.keyCode == 50 || e.keyCode == 98) NormalFadeOut(true);
			else if (e.keyCode == 51 || e.keyCode == 99) CustomFadeOut();
		}

		//ノーマル フェードアウト
		private function NormalFadeOut(_cache:Boolean):void {

			//キャッシュ
			this.cacheAsBitmap = _cache;

			//トゥイーン
			Tweener.addTween(this, {
				alpha		:0,
				time		:1.0,
				onComplete	:Reset
			});

			//フェードアウト
			function Reset():void {
				this.alpha = 1.0;
			}
		}

		//カスタム フェードアウト
		private function CustomFadeOut():void {

			//表示オブジェクトをビットマップ化
			var Copy_bmd:BitmapData = new BitmapData(stage.stageWidth, stage.stageHeight, true, 0x00000000);
			Copy_bmd.draw(this);
			var Copy_bmp:Bitmap = new Bitmap(Copy_bmd, "auto", false);

			//親オブジェクトに配置、レイヤー調整
			this.parent.addChild(Copy_bmp);
			this.parent.setChildIndex(DisplayObject(Copy_bmp), this.parent.getChildIndex(DisplayObject(this)));

			//自身を非表示
			this.alpha = 0.0;

			//親オブジェクトに配置したコピーをフェードアウト
			Tweener.addTween(Copy_bmp, {
				alpha				:0,
				time				:1.0,
				onComplete			:Reset,
				onCompleteParams	:[this]
			});

			//リセット
			function Reset(_this:Sample):void {
				_this.alpha = 1.0;
				_this.parent.removeChild(Copy_bmp);
				Copy_bmp = null;
				Copy_bmd.dispose();
				Copy_bmd = null;
			}
		}
	}
}

Max/MSPでビルドしたmxfファイルを、Windows7のRuntime（ver 5.1.3）で実行すると初回起動以降（初回はうまく動作します）、オーディオのI/Oデバイスが認識されなくなる（DSPステータスみるとDriverが「None」）場合の対処法。

手動で毎回ステータス画面を開いて設定するのは面倒なので、まず「admme@.txt」っていうファイルを検索して消去。次に、このファイルが入っていた「Max 5 Preferences Files」フォルダ（最初は不可視）を書き込み不可に。以上の2ステップです。
強制的に初期設定ファイルを作れないようにするだけですが、これで意図したとおりに動作してくれるはず。フォルダを書き込み不可にしたことによって、他の不具合が発生するかもしれないので、その場合は権限を調整して下さい。

解決方法ですが、「パブリッシュ設定」-「ハードウェアアクセラレーション」を「レベル2 – GPU」にするとちゃんと動きます。また、cmd（ctrl）+Fでフルスクリーンと通常の表示方法を10回くらい切り替えていると、何故かちゃんと動き出したりします。

また、Flash IDE上のライブラリに登録してビットマップ画像を配置・操作するよりも、プログラムのLoaderを使って画像ファイルを外部から読み込んで操作した方が、大きい画像や重い処理を実行できる場合が多いです。

さらに、デバッグモードやプレビューモードで実行するより、コンパイルしたものの方が扱える画像が増える場合があります。PCのスペックに依存すると思いますが、Core2QuadのPCで100枚以上の1000×1000の24bitのPNG画像を読み込み、碁盤目状に配置し操作することはできました。さらに500×500の24bitのPNG画像を100枚読み込むと、コンパイルしたexeでは動作しますが、デバッグモードでは動かなかったです。エラーが出ない場合があるので注意が必要。

XREA Plus（XREA Freeでも同じ？）に rep2「rev.101010.2210」を設置するメモです。自動ポップアップが表示できなくてハマリました。rep2の設置はXREAの規約に違反するかもしれないので自己責任でお願いします。

1. ダウンロード

まず「rep2expack ダウンロード」から「依存ライブラリ込み」をダウンロードします。ダウンロード後、解凍してできる「rep2」フォルダ内のいくつかのファイルを下記のように直します。

2. アクセス解除

自分のPCからrep2にアクセスできるようIPアドレスを登録にします。自分のアドレスが分からない場合は「グローバルIP 確認」でググれば色んなサイトが引っかかります。
conf/conf_hostcheck.php
36行目を変更
‘custom’ => 1,
50行目に追加
‘XXX.XXX.XXX.XXX’ => 24, //調べた自分のIPアドレスを追加

3. プライバシー対策

プライバシー（セキュリティ）が気になる人は、「public_html」ど同階層などにデータ保存フォルダのディレクトリ位置、ディレクトリ名を変更します。
conf_admin.inc.php
14,17,20,23行目を変更
$_conf['data_dir'] = “./data”; // (“./data”)
$_conf['dat_dir'] = “./data”; // (“./data”)
$_conf['idx_dir'] = “./data”; // (“./data”)
$_conf['pref_dir'] = “./data”; // (“./data”)
$_conf['db_dir'] = “./data/db”; // (“./data/db”)

4. レス修正

XREAサーバー経由だと公開プロクシ判断されレスできないので、直接スレをブラウザで開いて、レスができるように変更。
conf/conf_admin.inc.php
87行目を変更
$_conf['disable_res'] = 1; // (0)

5. PHP対策 1

PHPバージョンが推奨より古いためバージョンチェックを回避。
conf/conf.inc.php
193行目を変更（コメントアウト）
//p2_check_environment(__LINE__);

6. PHP対策 2

私がどこにあるのか分からずにハマったのはこの部分。レス番号の自動ポップアップ、URLの自動リンクが動作しないので、コメントアウトされている機能を動作するように変更。
lib/ShowThread.php
840行目と847行目を削除
/* と */ です。

7. PHP対策 3

PHPをCGIとして動作させるため、rep2フォルダ直下に「.htaccess」ファイルを作成し、テキストエディタなどで下記の文を書いて保存。
AddHandler application/x-httpd-phpcgi .php

8. アップロード

以上で一通りのファイル修正が完了です。rep2のフォルダをFTPソフトで自信のXREAサーバーにアップロードし、ユーザー名とパスワードを設定（初アクセス時）して使いましょう。

NUTSU 「2次ベジェ曲線の交点」
任意の2次ベジェ曲線同士の交点は、むりやり求めるしかない。かなりCPUに不可がかかるので、交点が100個以上とかある場合、毎フレーム実行させると処理落ちが発生する。また、上記リンク先で公開しているライブラリでは、ベジェ曲線を内包する短形が計算のベースになっているので、短形を描けない直線（コントロールポイントが2点の間にある）の場合は、別のスクリプトを書く必要がある。

memo 「ArgumentError: Error #2015: BitmapData が無効です。エラーの謎」
#2015のエラーが起こる場合、原因はnew BitmapData() によるメモリ不足が考えられるので
不要になったBitmapDataはdispose()で開放してあげなければいけない。それでもエラーが無くならない場合、PCのスペックを超過している恐れがある。しかし、ムービプレビューでエラーが起きても、デバッグモードやコンパイルした場合にはエラーが起きないこともあるので、限界ギリギリのパフォーマンスを求めるなら試してみる。

下記の参考スクリプトの2つの関数、RotateA()とRotateB()は、結果は同じになりますが、アプローチが少し違います。どちらの関数も引数は「操作したいオブジェクト、基準点の座標、相対回転角度」になっています。

RotateA()が、いつも自分で使っている方法。まず、回転させる直前と直後に指定したオブジェクトの親視点で基準点の位置を取得。この差分だけ回転した直後にオブジェクトを移動し位置を補正します。

RotateB()はオブジェクトの基準点自体を移動させる方法。最近読んだ_level0.KAYAC 「getBounds + Matrixで、もう基準点にはこだわらない。」を参考にしました。Matrixを使っているあたり、こっちの方がプロっぽいです。cellfusion blog 「DisplayObject.transform.matrix」でもほぼ同じ方法を紹介しています。

この2つの方法以外にも、オブジェクトを入れ子にして操作する方法がありますが、あまりスマートではないので省略します。

package {
	import flash.display.Graphics;
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.geom.Matrix;
	import flash.geom.Point;
	import flash.geom.Rectangle;

	public class Main extends MovieClip {

		//オブジェクト
		private var Sample_mc:MovieClip;
		private var Point_mc:MovieClip;

		//動作タイプ
		private var check:Boolean;

		public function Main():void {

			//オブジェクト（グレーの四角）を描画
			Sample_mc = new MovieClip();
			this.addChild(Sample_mc);
			Sample_mc.x = 200;
			Sample_mc.y = 150;
			var g:Graphics = Sample_mc.graphics;
			g.beginFill(0x999999, 1);
			g.drawRect(-10, -10, 200, 150);

			//基準点を描画
			Point_mc = new MovieClip();
			this.addChild(Point_mc);

			//初期値
			check = true;

			//リスナー登録
			this.addEventListener(Event.ENTER_FRAME, Update);
			stage.addEventListener(KeyboardEvent.KEY_DOWN, Change);
		}

		//動作タイプを変更
		private function Change(e:Event):void {

			//更新
			check = !check;
		}

		//表示更新
		private function Update(e:Event):void {

			//回転
			if (check) RotateA(Sample_mc, new Point(200, 200), 1);
			else RotateB(Sample_mc, new Point(300, 150), -2);
		}

		//回転
		private function RotateA(_object:MovieClip, _p:Point, _rotation:Number):void {

			//基準点を描画
			Draw(_p);

			//基準点をステージ上の座標で設定
			var p:Point = _object.globalToLocal(_p);

			//変更前の座標を取得
			var a:Point = _object.localToGlobal(p);

			//回転
			_object.rotation += _rotation;

			//変更後の座標を取得
			var b:Point = _object.localToGlobal(p);

			//差を補正
			var c:Point = a.subtract(b);
			_object.x += c.x;
			_object.y += c.y;
		}

		//回転
		private function RotateB(_object:MovieClip, _p:Point, _rotation:Number):void {

			//基準点を描画
			Draw(_p);

			//現状のマトリクスを取得
			var mx:Matrix = _object.transform.matrix;

			//オブジェクトの領域を取得
			var r:Rectangle = _object.getBounds(_object.parent);

			//基準点を任意の座標に変更
			mx.translate(-_p.x, -_p.y);

			//回転
			mx.rotate(_rotation / 180 * Math.PI);

			//基準点を初期位置に戻す
			mx.translate(_p.x, _p.y);

			//反映
			_object.transform.matrix = mx;
		}

		//基準点を描画
		private function Draw(_p:Point):void {

			//赤点を描画
			var g:Graphics = Point_mc.graphics;
			g.clear();
			g.beginFill(0xFF0000, 1);
			g.drawCircle(_p.x, _p.y, 5);
		}
	}
}

XMLファイル保存時など、Boolean型のデータをそのまま書き出すと文字列の “true” か “false” になりますが、読み込み時に、この文字列を強制型変換すると “true” “false” のどちらもtrueになってしまいます。読み込む時は強制型変換はせずに、文字列の等価性（==）を見るようにしましょう。

以下はキーボードが押された場合に、同階層のSample.xmlを読み込んで、trueかfalseを強制Boolean型変換かStringの判定で出力するサンプルコード。

//Sample.xml
<data>
  <a>true</a>
  <b>false</b>
</data>

//Main.as
package {
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	import flash.net.URLLoader;
	import flash.net.URLRequest;

	public class Main extends MovieClip {

		public function Main():void {

			//リスナー登録
			stage.addEventListener(KeyboardEvent.KEY_DOWN, KeyDown);
		}

		//キーボードが押された場合
		private function KeyDown(e:KeyboardEvent):void {

			//XMLファイルの読み込み
			var request:URLRequest = new URLRequest("Sample.xml");
			var loader:URLLoader = new URLLoader(request);
			loader.dataFormat = "text";
			loader.addEventListener(Event.COMPLETE, Output);

			//出力
			function Output(e:Event):void {

				var xml:XML = new XML();
				xml = XML(loader.data);

				//Boolean型で処理
				if (Boolean(xml.a)) trace("Boolean A:true");
				else trace("Boolean A:false");
				if (Boolean(xml.b)) trace("Boolean B:true");
				else if (Boolean(xml.b)) trace("Boolean B:false");

				//String型で処理
				if (xml.a == "true") trace("String A:true");
				else trace("String A:false");
				if (xml.b == "true") trace("String B:true");
				else trace("String B:false");
			}
		}
	}
}